- Qt 6.9
- Qt WebEngine
- QML Types
- WebEngineAction
- Qt 6.9.2 Reference Documentation

# WebEngineAction QML Type

An action that represents a WebEngineView::WebAction. More...

Import Statement: | `import QtWebEngine`
Since: | QtWebEngine 1.8

- List of all members, including inherited members

## Properties

- enabled : bool
- iconName : string
- text : int

## Methods

- void trigger()

## Detailed Description

A WebEngineAction is returned by the WebEngineView::action() method. It provides information about the action, such as whether it is enabled.

The following code uses the WebEngineView::action() method to check if the copy action is enabled:

     var copyAction = webEngineView.action(WebEngineView.Copy);
     if (copyAction.enabled)
         console.log("Copy is enabled.");
     else
         console.log("Copy is disabled.");

A ToolButton can be connected to a WebEngineAction as follows:

                 ToolButton {
                     property int itemAction: WebEngineView.Back
                     text: webEngineView.action(itemAction).text
                     enabled: webEngineView.action(itemAction).enabled
                     onClicked: webEngineView.action(itemAction).trigger()
                     icon.name: webEngineView.action(itemAction).iconName
                     display: AbstractButton.TextUnderIcon
                 }

A context menu could be implemented like this:

             property Menu contextMenu: Menu {
                 Repeater {
                     model: [
                         WebEngineView.Back,
                         WebEngineView.Forward,
                         WebEngineView.Reload,
                         WebEngineView.SavePage,
                         WebEngineView.Copy,
                         WebEngineView.Paste,
                         WebEngineView.Cut,
                         WebEngineView.ChangeTextDirectionLTR,
                         WebEngineView.ChangeTextDirectionRTL,
                     ]
                     MenuItem {
                         text: webEngineView.action(modelData).text
                         enabled: webEngineView.action(modelData).enabled
                         onClicked: webEngineView.action(modelData).trigger()
                         icon.name: webEngineView.action(modelData).iconName
                         display: MenuItem.TextBesideIcon
                     }
                 }
             }

             onContextMenuRequested: function(request) {
                 if (customContextMenuOption.checked) {
                     request.accepted = true;
                     contextMenu.popup();
                 }
             }

## Property Documentation

enabled : bool `[read-only]`

This property holds whether the action is enabled.

iconName : string `[read-only]`

This property holds the name of the icon for the action. This name can be used to pick the icon from a theme.

text : int `[read-only]`

This property holds a textual description of the action.

## Method Documentation

void trigger()

Triggers the action.